一步步寫STM32 OS【三】PendSV與堆棧操作
加入技術交流群
一、什么是PendSV
本文引用地址：http://www.104case.com/article/201701/342823.htmPendSV是可懸起異常，如果我們把它配置最低優先級，那么如果同時有多個異常被觸發，它會在其他異常執行完畢后再執行，而且任何異常都可以中斷它。更詳細的內容在《Cortex-M3 權威指南》里有介紹，下面我摘抄了一段。
OS 可以利用它“緩期執行”一個異常——直到其它重要的任務完成后才執行動 作。懸起 PendSV 的方法是：手工往 NVIC的 PendSV懸起寄存器中寫 1。懸起后，如果優先級不夠 高，則將緩期等待執行。
PendSV的典型使用場合是在上下文切換時(在不同任務之間切換)。例如，一個系統中有兩個就緒的任務，上下文切換被觸發的場合可以是：
1、執行一個系統調用
2、系統滴答定時器(SYSTICK)中斷，(輪轉調度中需要)
讓我們舉個簡單的例子來輔助理解。假設有這么一個系統，里面有兩個就緒的任務，并且通過SysTick異常啟動上下文切換。但若在產生 SysTick 異常時正在響應一個中斷，則 SysTick異常會搶占其 ISR。在這種情況下，OS是不能執行上下文切換的，否則將使中斷請求被延遲，而且在真實系統中延遲時間還往往不可預知——任何有一丁點實時要求的系統都決不能容忍這 種事。因此，在 CM3 中也是嚴禁沒商量——如果 OS 在某中斷活躍時嘗試切入線程模式，將觸犯用法fault異常。
為解決此問題，早期的 OS 大多會檢測當前是否有中斷在活躍中，只有在無任何中斷需要響應 時，才執行上下文切換(切換期間無法響應中斷)。然而，這種方法的弊端在于，它可以把任務切 換動作拖延很久(因為如果搶占了 IRQ，則本次 SysTick在執行后不得作上下文切換，只能等待下 一次SysTick異常)，尤其是當某中斷源的頻率和SysTick異常的頻率比較接近時，會發生“共振”， 使上下文切換遲遲不能進行。現在好了，PendSV來完美解決這個問題了。PendSV異常會自動延遲上下文切換的請求，直到 其它的 ISR都完成了處理后才放行。為實現這個機制，需要把 PendSV編程為最低優先級的異常。如果 OS檢測到某 IRQ正在活動并且被 SysTick搶占，它將懸起一個 PendSV異常，以便緩期執行 上下文切換。
使用 PendSV 控制上下文切換個中事件的流水賬記錄如下：
1. 任務 A呼叫 SVC來請求任務切換(例如，等待某些工作完成)
2. OS接收到請求，做好上下文切換的準備，并且懸起一個 PendSV異常。
3. 當 CPU退出 SVC后，它立即進入 PendSV，從而執行上下文切換。
4. 當 PendSV執行完畢后，將返回到任務 B，同時進入線程模式。
5. 發生了一個中斷，并且中斷服務程序開始執行
6. 在 ISR執行過程中，發生 SysTick異常，并且搶占了該 ISR。
7. OS執行必要的操作，然后懸起 PendSV異常以作好上下文切換的準備。
8. 當 SysTick退出后，回到先前被搶占的 ISR中，ISR繼續執行
9. ISR執行完畢并退出后，PendSV服務例程開始執行，并且在里面執行上下文切換
10. 當 PendSV執行完畢后，回到任務 A，同時系統再次進入線程模式。
我們在uCOS的PendSV的處理代碼中可以看到：
OS_CPU_PendSVHandler
CPSID I ; 關中斷
;保存上文
;.......................
;切換下文
CPSIE I ;開中斷
BX LR ;異常返回
它在異常一開始就關閉了中端，結束時開啟中斷，中間的代碼為臨界區代碼，即不可被中斷的操作。PendSV異常是任務切換的堆棧部分的核心，由他來完成上下文切換。PendSV的操作也很簡單，主要有設置優先級和觸發異常兩部分：
NVIC_INT_CTRL EQU 0xE000ED04 ; 中斷控制寄存器
NVIC_SYSPRI14 EQU 0xE000ED22 ; 系統優先級寄存器(優先級14).
NVIC_PENDSV_PRI EQU 0xFF ; PendSV優先級(最低). NVIC_PENDSVSET EQU 0x10000000 ; PendSV觸發值
; 設置PendSV的異常中斷優先級
LDR R0, =NVIC_SYSPRI14
LDR R1, =NVIC_PENDSV_PRI
STRB R1, [R0] ; 觸發PendSV異常
LDR R0, =NVIC_INT_CTRL
LDR R1, =NVIC_PENDSVSET
STR R1, [R0]
二、堆棧操作
Cortex M4有兩個堆棧寄存器，主堆棧指針(MSP)與進程堆棧指針(PSP)，而且任一時刻只能使用其中的一個。MSP為復位后缺省使用的堆棧指針，異常永遠使用MSP，如果手動開啟PSP，那么線程使用PSP，否則也使用MSP。怎么開啟PSP?
MSR PSP, R0 ; Load PSP with new process SP
ORR LR, LR, #0x04 ; Ensure exception return uses process stack
很容易就看出來了，置LR的位2為1，那么異常返回后，線程使用PSP。
寫OS首先要將內存分配搞明白，單片機內存本來就很小，所以我們當然要斤斤計較一下。在OS運行之前，我們首先要初始化MSP和PSP，OS_CPU_ExceptStkBase是外部變量，假如我們給主堆棧分配1KB(256*4)的內存即OS_CPU_ExceptStk[256],則OS_CPU_ExceptStkBase=&OS_CPU_ExceptStk[256-1]。
EXTERN OS_CPU_ExceptStkBase
;PSP清零，作為首次上下文切換的標志
MOVS R0, #0
MSR PSP, R0
;將MSP設為我們為其分配的內存地址
LDR R0, =OS_CPU_ExceptStkBase
LDR R1, [R0]
MSR MSP, R1
然后就是PendSV上下文切換中的堆棧操作了，如果不使用FPU，則進入異常自動壓棧xPSR，PC，LR，R12，R0-R3，我們還要把R4-R11入棧。如果開啟了FPU，自動壓棧的寄存器還有S0-S15，還需吧S16-S31壓棧。
MRS R0, PSP
SUBS R0, R0, #0x20 ;壓入R4-R11
STM R0, {R4-R11}
LDR R1, =Cur_TCB_Point ;當前任務的指針
LDR R1, [R1]
STR R0, [R1] ; 更新任務堆棧指針
出棧類似，但要注意順序
LDR R1, =TCB_Point ;要切換的任務指針
LDR R2, [R1]
LDR R0, [R2] ; R0為要切換的任務堆棧地址
LDM R0, {R4-R11} ; 彈出R4-R11
ADDS R0, R0, #0x20
MSR PSP, R0 ;更新PSP
三、OS實戰
新建os_port.asm文件，內容如下：
NVIC_INT_CTRL EQU 0xE000ED04 ; Interrupt control state register.
NVIC_SYSPRI14 EQU 0xE000ED22 ; System priority register (priority 14).
NVIC_PENDSV_PRI EQU 0xFF ; PendSV priority value (lowest).
NVIC_PENDSVSET EQU 0x10000000 ; Value to trigger PendSV exception.
RSEG CODE:CODE:NOROOT(2)
THUMB
EXTERN g_OS_CPU_ExceptStkBase
EXTERN g_OS_Tcb_CurP
EXTERN g_OS_Tcb_HighRdyP
PUBLIC OSStart_Asm
PUBLIC PendSV_Handler
PUBLIC OSCtxSw
OSCtxSw
LDR R0, =NVIC_INT_CTRL
LDR R1, =NVIC_PENDSVSET
STR R1, [R0]
BX LR ; Enable interrupts at processor level
OSStart_Asm
LDR R0, =NVIC_SYSPRI14 ; Set the PendSV exception priority
LDR R1, =NVIC_PENDSV_PRI
STRB R1, [R0]
MOVS R0, #0 ; Set the PSP to 0 for initial context switch call
MSR PSP, R0
LDR R0, =g_OS_CPU_ExceptStkBase ; Initialize the MSP to the OS_CPU_ExceptStkBase
LDR R1, [R0]
MSR MSP, R1
LDR R0, =NVIC_INT_CTRL ; Trigger the PendSV exception (causes context switch)
LDR R1, =NVIC_PENDSVSET
STR R1, [R0]
CPSIE I ; Enable interrupts at processor level
OSStartHang
B OSStartHang ; Should never get here
PendSV_Handler
CPSID I ; Prevent interruption during context switch
MRS R0, PSP ; PSP is process stack pointer
CBZ R0, OS_CPU_PendSVHandler_nosave ; Skip register save the first time
SUBS R0, R0, #0x20 ; Save remaining regs r4-11 on process stack
STM R0, {R4-R11}
LDR R1, =g_OS_Tcb_CurP ; OSTCBCur->OSTCBStkPtr = SP;
LDR R1, [R1]
STR R0, [R1] ; R0 is SP of process being switched out
; At this point, entire context of process has been saved
OS_CPU_PendSVHandler_nosave
LDR R0, =g_OS_Tcb_CurP ; OSTCBCur = OSTCBHighRdy;
LDR R1, =g_OS_Tcb_HighRdyP
LDR R2, [R1]
STR R2, [R0]
LDR R0, [R2] ; R0 is new process SP; SP = OSTCBHighRdy->OSTCBStkPtr;
LDM R0, {R4-R11} ; Restore r4-11 from new process stack
ADDS R0, R0, #0x20
MSR PSP, R0 ; Load PSP with new process SP
ORR LR, LR, #0x04 ; Ensure exception return uses process stack
CPSIE I
BX LR ; Exception return will restore remaining context
END
main.c內容如下：
#include "stdio.h"
#define OS_EXCEPT_STK_SIZE 1024
#define TASK_1_STK_SIZE 1024
#define TASK_2_STK_SIZE 1024
typedef unsigned int OS_STK;
typedef void (*OS_TASK)(void);
typedef struct OS_TCB
{
OS_STK *StkAddr;
}OS_TCB,*OS_TCBP;
OS_TCBP g_OS_Tcb_CurP;
OS_TCBP g_OS_Tcb_HighRdyP;
static OS_STK OS_CPU_ExceptStk[OS_EXCEPT_STK_SIZE];
OS_STK *g_OS_CPU_ExceptStkBase;
static OS_TCB TCB_1;
static OS_TCB TCB_2;
static OS_STK TASK_1_STK[TASK_1_STK_SIZE];
static OS_STK TASK_2_STK[TASK_2_STK_SIZE];
extern void OSStart_Asm(void);
extern void OSCtxSw(void);
void Task_Switch()
{
if(g_OS_Tcb_CurP == &TCB_1)
g_OS_Tcb_HighRdyP=&TCB_2;
else
g_OS_Tcb_HighRdyP=&TCB_1;
OSCtxSw();
}
void task_1()
{
printf("Task 1 Running!!!n");
Task_Switch();
printf("Task 1 Running!!!n");
Task_Switch();
}
void task_2()
{
printf("Task 2 Running!!!n");
Task_Switch();
printf("Task 2 Running!!!n");
Task_Switch();
}
void Task_End(void)
{
printf("Task Endn");
while(1)
{}
}
void Task_Create(OS_TCB *tcb,OS_TASK task,OS_STK *stk)
{
OS_STK *p_stk;
p_stk = stk;
p_stk = (OS_STK *)((OS_STK)(p_stk) & 0xFFFFFFF8u);
*(--p_stk) = (OS_STK)0x01000000uL; //xPSR
*(--p_stk) = (OS_STK)task; // Entry Point
*(--p_stk) = (OS_STK)Task_End; // R14 (LR)
*(--p_stk) = (OS_STK)0x12121212uL; // R12
*(--p_stk) = (OS_STK)0x03030303uL; // R3
*(--p_stk) = (OS_STK)0x02020202uL; // R2
*(--p_stk) = (OS_STK)0x01010101uL; // R1
*(--p_stk) = (OS_STK)0x00000000u; // R0
*(--p_stk) = (OS_STK)0x11111111uL; // R11
*(--p_stk) = (OS_STK)0x10101010uL; // R10
*(--p_stk) = (OS_STK)0x09090909uL; // R9
*(--p_stk) = (OS_STK)0x08080808uL; // R8
*(--p_stk) = (OS_STK)0x07070707uL; // R7
*(--p_stk) = (OS_STK)0x06060606uL; // R6
*(--p_stk) = (OS_STK)0x05050505uL; // R5
*(--p_stk) = (OS_STK)0x04040404uL; // R4
tcb->StkAddr=p_stk;
}
int main()
{
g_OS_CPU_ExceptStkBase = OS_CPU_ExceptStk + OS_EXCEPT_STK_SIZE - 1;
Task_Create(&TCB_1,task_1,&TASK_1_STK[TASK_1_STK_SIZE-1]);
Task_Create(&TCB_2,task_2,&TASK_2_STK[TASK_1_STK_SIZE-1]);
g_OS_Tcb_HighRdyP=&TCB_1;
OSStart_Asm();
return 0;
}
編譯下載并調試：
在此處設置斷點
此時寄存器的值，可以看到R4-R11正是我們給的值，單步運行幾次，可以看到進入了我們的任務task_1或task_2，任務里打印信息，然后調用Task_Switch進行切換，OSCtxSw觸發PendSV異常。
IO輸出如下：
至此我們成功實現了使用PenSV進行兩個任務的互相切換。之后，我們使用使用SysTick實現比較完整的多任務切換。
評論