51單片機(jī)用PWM控制LED漸亮與漸滅

設(shè)計(jì)思路：用定時(shí)器中斷產(chǎn)生最小時(shí)間單位T0，每m個(gè)T0組成一個(gè)子周期T10，其中前n個(gè)T0為LED導(dǎo)通時(shí)間，即Ton=n*T0,則Toff=(m-n)*T0

;每X個(gè)T10組成一個(gè)母周期T20，其中前y個(gè)T10為有效控制時(shí)間，后續(xù)的（x-y)個(gè)T10令LED熄滅或者子周期占空比調(diào)至最小。

;適當(dāng)調(diào)節(jié)n/m和x/y的比例使顯示效果達(dá)到最佳。

;以下是剛剛調(diào)試通過的小段程序，顯示效果良好。

;子周期的最小占空比的寬度應(yīng)大于LED的點(diǎn)亮?xí)r間，即點(diǎn)亮LED的時(shí)間寬度n/m*T0應(yīng)足夠產(chǎn)生余輝。類似于動(dòng)態(tài)數(shù)碼管對點(diǎn)亮?xí)r間的要求。

;母周期的寬度應(yīng)小于1/50s，提高刷新頻率以令肉眼察覺不出閃爍。

;芯片: AT89C2051

;晶振：18.9375

;電路描述：輸入5V電源，簡易RC復(fù)位，P3.3對地接KEY(減1)，P3.3對地接KEY2(加1)，P3.7接三極管C106驅(qū)動(dòng)LED。LED直徑5mm，紅色。限流電阻471、1/4W.

;功能描述：LED漸亮漸滅。按住KEY可以保持住當(dāng)前某占空比的亮度（如一開始按住KEY再通電，將看到空度比為1%的亮度）。

;調(diào)節(jié)子周期和母周期，均可漸亮漸滅。 同時(shí)按下“加1”和“減1”按鍵切換選擇調(diào)節(jié)對象(2004.11.04)

LED BIT P3.7
KEY BIT P3.3
SOV BIT 20H.0 ;子周期顯示完畢標(biāo)志
BOV BIT 20H.1 ;母周期顯示完畢標(biāo)志
SSS EQU 30H ;子周期占空寬度調(diào)節(jié)
T10 EQU 31H ;子周期寬度
AAA EQU 32H ;子周期占空寬度入口
BBB EQU 33H ;母周期占空寬度入口
T20 EQU 34H ;母周期寬度
MMM EQU 35H ;母周期占空寬度調(diào)節(jié)
A10 EQU 36H ;子周期寬度緩沖
B20 EQU 37H ;母周期寬度緩沖

KEY2 BIT P3.2
COM1 BIT P3.5
COM2 BIT P3.4
COM3 BIT P3.1
COM4 BIT P3.0
NOISE1 EQU 38H
NOISE2 EQU 39H
NOISE3 EQU 3AH

ORG 00H
LJMP MAIN
ORG 0BH
LJMP PWM

PWM:
MOV TH0,#0FFH
MOV TL0,#90H
PUSH ACC
;####################################################
JB BOV,OUTLOW
;*********************************************
JB SOV,IFSEND
DEC T10 ;保持計(jì)數(shù)同步
DJNZ SSS,LRET ;占空參數(shù)修正
MOV SSS,AAA ;復(fù)原子周期占空參數(shù)
MOV A,T10
CJNE A,#0,SCTN ;對占空比為100%時(shí)的修正
AJMP T10END
SCTN:
CLR LED
SETB SOV
AJMP LRET
IFSEND:
DJNZ T10,LRET
T10END:
MOV T10,A10 ;復(fù)原子周期寬度參數(shù)
SETB LED
CLR SOV ;子周期處理完畢
;**********************************************
DEC T20
DJNZ MMM,LRET
MOV MMM,BBB
MOV A,T20
CJNE A,#0,MCTN ;對占空比為100%時(shí)的修正
AJMP T20END
MCTN:
CLR LED
SETB BOV
AJMP LRET
OUTLOW:
CLR LED ;母周期低電平部分輸出0DJNZ T10,LRET
MOV T10,A10
DJNZ T20,LRET
T20END:
MOV T20,B20
SETB LED
CLR BOV ;母周期處理完畢
;#############################
LRET:
POP ACC
RETI

MAIN:
MOV P3,#00001100B
MOV TMOD,#01H
MOV A10,#10 ;子周期寬設(shè)置
MOV B20,#20 ;母周期寬設(shè)置
MOV T10,A10
MOV T20,B20
MOV AAA,#6 ;子周初始占空寬度設(shè)置
MOV BBB,#20 ;母周初始占空寬度設(shè)置
MOV SSS,AAA
MOV MMM,BBB
SETB ET0
SETB TR0
SETB EA
SETB LED
MOV 20H,#0;所有標(biāo)志位清零
MOV R0,#250
MOV R1,#2 ;每隔0.07*250*2ms調(diào)節(jié)一次亮度

FREE: ;KEY BBBBBBBBBBBBBBBBBBBBBBBBBBBB
MOV PCON,#1
CHANGE2:
JB KEY,CHOU1
JB KEY2,CHOU1
DJNZ NOISE1,FREE
JNB KEY,$
JNB KEY2,$
AJMP FREE3
CHOU1:
MOV NOISE1,#0
DOWN1:
JB KEY,UP1
DJNZ NOISE2,FREE
DJNZ BBB,NEXT ;減1修正
MOV BBB,#1
NEXT:
JB KEY,FREE ;操作完成后待松鍵再退出
JNB KEY2,FREE
SJMP NEXT
UP1:
MOV NOISE2,#0
IFUP:
JB KEY2,LCRNOS
DJNZ NOISE3,FREE
INC BBB ;加1修正
MOV A,BBB
CJNE A,#21,NEXT2
MOV BBB,#20
NEXT2:
JB KEY2,FREE ;操作完成后待松鍵再退出
JNB KEY,FREE
SJMP NEXT2
LCRNOS:
MOV NOISE3,#0
AJMP FREE ;KEY B

FREE3: ;KEY
MOV PCON,#1
CHANGE1:
JB KEY,CHOU2
JB KEY2,CHOU2
DJNZ NOISE1,FREE3
JNB KEY,$
JNB KEY2,$
AJMP FREE
CHOU2:
MOV NOISE1,#0
DOWN2:
JB KEY,UP2
DJNZ NOISE2,FREE3
DJNZ AAA,NEXT3 ;減1修正
MOV AAA,#1
NEXT3:
JB KEY,FREE3 ;操作完成后待松鍵再退出
JNB KEY2,FREE3
SJMP NEXT3
UP2:
MOV NOISE2,#0
IFUP2:
JB KEY2,LCRNOS2
DJNZ NOISE3,FREE3
INC AAA ;加1修正
MOV A,AAA
CJNE A,#11,NEXT4
MOV AAA,#10
NEXT4:
JB KEY2,FREE3 ;操作完成后待松鍵再退出
JNB KEY,FREE3
SJMP NEXT4
LCRNOS2:
MOV NOISE3,#0
AJMP FREE3 ;

END