PIC系列單片機程序相關問題

先介紹二條偽指令：
EQU --標號賦值偽指令
ORG --地址定義偽指令更多芯片資料 http://www.icdec.com
PIC16C5X單片機在RESET后指令計算器PC被置為全“1”,所以PIC16C5X幾種型號芯片的復位地址為：
PIC16C54/55:1FFH
PIC16C56:3FFH
PIC16C57/58:7FFH
一般來說，PIC單片機的源程序并沒有要求統一的格式，大家可以根據自己的風格來編寫。但這里我們推薦一種清晰明了的格式供參考。
TITLE This is …… ;程序標題
;--------------------------------------
;名稱定義和變量定義
;--------------------------------------
F0 EQU 0
RTCC EQU 1
PC EQU 2
STATUS EQU 3
FSR EQU 4
RA EQU 5
RB EQU 6
RC EQU 7
┋
PIC16C54 EQU 1FFH ;芯片復位地址
PIC16C56 EQU 3FFH
PIC16C57 EQU 7FFH
;-----------------------------------------
ORG PIC16C54 GOTO MAIN ;在復位地址處轉入主程序
ORG 0 ;在0000H開始存放程序
;-----------------------------------------
;子程序區
;-----------------------------------------
DELAY MOVLW 255
┋
RETLW 0
;------------------------------------------
;主程序區
;------------------------------------------
MAIN
MOVLW B00000000
TRIS RB ;RB已由偽指令定義為6,即B口
┋
LOOP
BSF RB,7 CALL DELAY
BCF RB,7 CALL DELAY
┋
GOTO LOOP
;-------------------------------------------
END ;程序結束
注：MAIN標號一定要處在0頁面內。
2、PIC單片機程序設計基礎
1） 設置 I/O 口的輸入/輸出方向
PIC16C5X單片機的I/O 口皆為雙向可編程，即每一根I/O 端線都可分別單獨地由程序設置為輸入或輸出。這個過程由寫I/O控制寄存器TRIS f來實現，寫入值為“1”,則為輸入；寫入值為“0”,則為輸出。
MOVLW 0FH ;0000 1111（0FH）
輸入 輸出
TRIS 6 ;將W中的0FH寫入B口控制器，
;B口高4位為輸出，低4位為輸入。
MOVLW 0C0H ; 11 000000（0C0H）
RB4,RB5輸出0 RB6,RB7輸出1
2） 檢查寄存器是否為零
如果要判斷一個寄存器內容是否為零，很簡單，現以寄存器F10為例：
MOVF 10,1 ;F10→F10,結果影響零標記狀態位Z
BTFSS STATUS,Z ;F10為零則跳
GOTO NZ ;Z=0即F10不為零轉入標號NZ處程序
┋ ;Z=1即F10=0處理程序
3） 比較二個寄存器的大小
要比較二個寄存器的大小，可以將它們做減法運算，然后根據狀態位C來判斷。注意，相減的結果放入W,則不會影響二寄存器原有的值。
例如F8和F9二個寄存器要比較大小：
MOVF 8,0 ;F8→W
SUBWF 9,0 ;F9-W（F8）→W
BTFSC STATUS,Z ;判斷F8=F9否
GOTO F8=F9
BTFSC STATUS,C ;C=0則跳
GOTO F9>F8 ;C=1相減結果為正，F9>F8
GOTO F9 ;C=0相減結果為負，F9┋
4） 循環n次的程序
如果要使某段程序循環執行n次，可以用一個寄存器作計數器。下例以F10做計數器，使程序循環8次。
COUNT EQU 10 ;定義F10名稱為COUNT（計數器）
┋
MOVLW 8
MOVWF COUNT LOOP ;循環體
LOOP
┋
DECFSZ COUNT,1 ;COUNT減1,結果為零則跳
GOTO LOOP ;結果不為零，繼續循環
┋ ;結果為零，跳出循環
5）“IF……THEN……”格式的程序
下面以“IF X=Y THEN GOTO NEXT”格式為例。
MOVF X,0 ;X→W
SUBWF Y,0 ;Y-W（X）→W
BTFSC STATUS,Z ;X=Y 否
GOTO NEXT ;X=Y,跳到NEXT去執行。
┋ ;X≠Y
6）“FOR……NEXT”格式的程序
“FOR……NEXT”程序使循環在某個范圍內進行。下例是“FOR X=0 TO 5”格式的程序。F10放X的初值，F11放X的終值。
START EQU 10
DAEND EQU 11
┋
MOVLW 0
MOVWF START ; 0→START（F10）
MOVLW 5
MOVWF DAEND ;5→DAEND（F11）
LOOP
┋
INCF START,1 ;START值加1
MOVF START,0
SUBWF DAEND,0 ;START=DAEND ?（X=5否）
BTFSS STATUS,Z
GOTO LOOP ;X<5,繼續循環
┋ ;X=5,結束循環
7）“DO WHILE……END”格式的程序
“DO WHILE……END”程序是在符合條件下執行循環。下例是“DO WHILE X=1”格式的程序。F10放X的值。
X EQU 10
┋
MOVLW 1
MOVWF X ;1→X（F10），作為初值
LOOP
┋
MOVLW 1
SUBWF X,0
BTFSS STATUS,Z ;X=1否？
GOTO LOOP ;X=1繼續循環
┋ ;X≠1跳出循環
8） 查表程序
查表是程序中經常用到的一種操作。下例是將十進制0~9轉換成7段LED數字顯示值。若以B口的RB0~RB6來驅動LED的a~g線段，則有如下關系：
設LED為共陽，則0~9數字對應的線段值如下表： 十進數 線段值 十進數 線段值
0 C0H 5 92H
1 C9H 6 82H
2 A4H 7 F8H
3 B0H 8 80H
4 99H 9 90H
PIC單片機的查表程序可以利用子程序帶值返回的特點來實現。具體是在主程序中先取表數據地址放入W,接著調用子程序，子程序的第一條指令將W置入PC,則程序跳到數據地址的地方，再由“RETLW”指令將數據放入W返回到主程序。下面程序以F10放表頭地址。
MOVLW TABLE ;表頭地址→F10
MOVWF 10
┋
MOVLW 1 ;1→W,準備取“1”的線段值
ADDWF 10,1 ;F10+W =“1”的數據地址
CALL CONVERT
MOVWF 6 ;線段值置到B口，點亮LED
┋
CONVERT MOVWF 2 ;W→PC TABLE
RETLW 0C0H ;“0”線段值
RETLW 0F9H ;“1”線段值
┋
RETLW 90H ;“9”線段值
9）“READ……DATA,RESTORE”格式程序
“READ……DATA”程序是每次讀取數據表的一個數據，然后將數據指針加1,準備取下一個數據。下例程序中以F10為數據表起始地址，F11做數據指針。
POINTER EQU 11 ;定義F11名稱為POINTER
┋
MOVLW DATA
MOVWF 10 ;數據表頭地址→F10
CLRF POINTER ;數據指針清零
┋
MOVF POINTER,0
ADDWF 10,0 ;W =F10+POINTER
┋
INCF POINTER,1 ;指針加1
CALL CONVERT ;調子程序，取表格數據
┋
CONVERT MOVWF 2 ;數據地址→PC
DATA RETLW 20H ;數據
┋
RETLW 15H ;數據
如果要執行“RESTORE”,只要執行一條“CLRF POINTER”即可。
10） 延時程序
如果延時時間較短，可以讓程序簡單地連續執行幾條空操作指令“NOP”.如果延時時間長，可以用循環來實現。下例以F10計算，使循環重復執行100次。
MOVLW D100
MOVWF 10
LOOP DECFSZ 10,1 ;F10-1→F10,結果為零則跳
GOTO LOOP
┋
延時程序中計算指令執行的時間和即為延時時間。如果使用4MHz振蕩，則每個指令周期為1μS.所以單周期指令時間為1μS,雙周期指令時間為2μS.在上例的LOOP循環延時時間即為：（1+2）*100+2=302（μS）。在循環中插入空操作指令即可延長延時時間：
MOVLW D100
MOVWF 10
LOOP NOP
NOP
NOP
DECFSZ 10,1
GOTO LOOP
┋
延時時間=（1+1+1+1+2）*100+2=602（μS）。
用幾個循環嵌套的方式可以大大延長延時時間。下例用2個循環來做延時：
MOVLW D100
MOVWF 10
LOOP MOVLW D16
MOVWF 11
LOOP1 DECFSZ 11,1
GOTO LOOP1
DECFSZ 10,1
GOTO LOOP
┋
延時時間=1+1+[1+1+（1+2）*16-1+1+2]*100-1=5201（μS）
11） PIC單片機RTCC計數器的使用
RTCC是一個脈沖計數器，它的計數脈沖有二個來源，一個是從RTCC引腳輸入的外部信號，一個是內部的指令時鐘信號。可以用程序來選擇其中一個信號源作為輸入。RTCC可被程序用作計時之用；程序讀取RTCC寄存器值以計算時間。當RTCC作為內部計時器使用時需將RTCC管腳接VDD或VSS,以減少干擾和耗電流。下例程序以RTCC做延時：
RTCC EQU 1
┋
CLRF RTCC ;RTCC清0
MOVLW 07H
OPTION ;選擇預設倍數1:256→RTCC
LOOP MOVLW 255 ;RTCC計數終值
SUBWF RTCC,0
BTFSS STATUS,Z ;RTCC=255?
GOTO LOOP
┋
這個延時程序中，每過256個指令周期RTCC寄存器增1（分頻比=1:256），設芯片使用4MHz振蕩，則：
延時時間=256*256=65536（μS）
RTCC是自振式的，在它計數時，程序可以去做別的事情，只要隔一段時間去讀取它，檢測它的計數值即可。
12） 寄存器體（BANK）的尋址
對于PIC16C54/55/56,寄存器有32個，只有一個體（BANK），故不存在體尋址問題，對于PIC16C57/58來說，寄存器則有80個，分為4個體（BANK0-BANK3）。在對F4（FSR）的說明中可知，F4的bit6和bit5是寄存器體尋址位，其對應關系如下：
Bit6 Bit5 BANK 物理地址
0 0 BANK0 10H~1FH
0 1 BANK1 30H~3FH
1 0 BANK2 50H~5FH
1 1 BANK3 70H~7FH
當芯片上電RESET后，F4的bit6,bit5是隨機的，非上電的RESET則保持原先狀態不變。
下面的例子對BANK1和BANK2的30H及50H寄存器寫入數據。
例1.（設目前體選為BANK0）
BSF 4,5 ;置位bit5=1,選擇BANK1
MOVLW DATA
MOVWF 10H ; DATA→30H
BCF 4,5
BSF 4,6 ;bit6=1,bit5=0選擇BANK2
MOVWF 10H ;DATA→50H
從上例中我們看到，對某一體（BANK）中的寄存器進行讀寫，首先要先對F4中的體尋址位進行操作。實際應用中一般上電復位后先清F4的bit6和bit5為0,使之指向BANK0,以后再根據需要使其指向相應的體。
注意，在例子中對30H寄存器（BANK1）和50H寄存器（BANK2）寫數時，用的指令“MOVWF 10H”中寄存器地址寫的都是“10H”,而不是讀者預期的“MOVWF 30H”和“MOVWF 50H”,為什么？
讓我們回顧一下指令表。在PIC16C5X的所有有關寄存器的指令碼中，寄存尋址位都只占5個位：fffff,只能尋址32個（00H-1FH）寄存器。所以要選址80個寄存器，還要再用二位體選址位PA1和PA0.當我們設置好體尋址位PA1和PA0,使之指向一個BANK,那么指令“MOVWF 10H”就是將W內容置入這個BANK中的相應寄存器內（10H,30H,50H,或70H）。
有些設計者第一次接觸體選址的概念，難免理解上有出入，下面是一個例子：
例2:（設目前體選為BANK0）
MOVLW 55H
MOVWF 30H ;欲把55H→30H寄存器
MOVLW 66H
MOVWF 50H ;欲把66H→50H寄存器
以為“MOVWF 30H”一定能把W置入30H,“MOVWF 50H”一定能把W置入50H,這是錯誤的。因為這兩條指令的實際效果是“MOVWF 10H”,原因上面已經說明過了。所以例2這段程序最后結果是F10H=66H,而真正的F30H和F50H并沒有被操作到。
建議：為使體選址的程序清晰明了，建議多用名稱定義符來寫程序，則不易混淆。 例3:假設在程序中用到BANK0,BANK1,BANK2的幾個寄存器如下：
BANK0 地址 BANK1 地址 BANK2 地址 BANK3 地址
A 10H B 30H C 50H · 70H
· · · · · · · ·
· · · · · · · ·
A EQU 10H ;BANK0
B EQU 10H ;BANK1
C EQU 10H ;BANK2
┋
FSR EQU 4
Bit6 EQU 6
Bit5 EQU 5
DATA EQU 55H
┋
MOVLW DATA
MOVWF A
BSF FSR,Bit5
MOVWF B ;DATA→F30H
BCF FSR,Bit5
BSF FSR,Bit6
MOVWF C ;DATA→F50H
┋
程序這樣書寫，相信體選址就不容易錯了。
13） 程序跨頁面跳轉和調用
下面介紹PIC16C5X單片機的程序存儲區的頁面概念和F3寄存器中的頁面選址位PA1和PA0兩位應用的實例。
（1）“GOTO”跨頁面
例：設目前程序在0頁面（PAGE0），欲用“GOTO”跳轉到1頁面的某個地方
KEY（PAGE1）。
STATUS EQU 3
PA1 EQU 6
PA0 EQU 5
┋
BSF STATUS,PA0 ;PA0=1,選擇PAGE頁面
GOTO KEY ;跨頁跳轉到1頁面的KEY
┋
KEY NOP ;1頁面的程序
┋
（2）“CALL”跨頁面
例：設目前程序在0頁面（PAGE0），現在要調用--放在1頁面（PAGE1）的子程序DELAY.
┋
BSF STATUS,PA0 ;PA0=1,選擇PAGE1頁面
CALL DELAY ;跨頁調用
BCF STATUS,PA0 ;恢復0頁面地址
┋
DELAY NOP ;1頁面的子程序
┋
注意：程序為跨頁CALL而設了頁面地址，從子程序返回后一定要恢復原來的頁面地址。
（3）程序跨頁跳轉和調用的編寫
讀者看到這里，一定要問：我寫源程序（。ASM）時，并不去注意每條指令的存放地址，我怎么知道這個GOTO是要跨頁面的，那個CALL是需跨頁面的？的確，開始寫源程序時并知道何時會發生跨頁面跳轉或調用，不過當你將源程序匯編時，就會自動給出。當匯編結果顯示出：
X X X（地址）“GOTO out of Range”
X X X（地址）“CALL out of Range”
這表明你的程序發生了跨頁面的跳轉和調用，而你的程序中在這些跨頁GOTO和CALL之前還未設置好相應的頁面地址。這時應該查看匯編生成的。LST文件，找到這些GOTO和CALL,并查看它們要跳轉去的地址處在什么頁面，然后再回到源程序（。ASM）做必要的修改。一直到你的源程序匯編通過（0 Errors and Warnnings）。
（4）程序頁面的連接
程序4個頁面連接處應該做一些處理。一般建議采用下面的格式： 即在進入另一個頁面后，馬上設置相應的頁面地址位（PA1,PA0）。頁面處理是PIC16C5X編程中最麻煩的部分，不過并不難。只要做了一次實際的編程練習后，就能掌握了。