S3C2440 2440init.s分析第一篇（一）

在網(wǎng)上轉(zhuǎn)的，收集起來(lái)，下次要查看的時(shí)候方便點(diǎn)。

s3c2440啟動(dòng)文件分析
s3c2440啟動(dòng)文件分析
;=========================================

; [url=URL]NAME[/url]: 2440INIT.S

; DESC: C start up codes

; Configure memory, ISR ,stacks

; Initialize C-variables

; HISTORY:

; 2002.02.25:kwtark: ver 0.0

; 2002.03.20:purnnamu: Add some functions for testing STOP,Sleep mode

; 2003.03.14:DonGo: Modified for 2440.

;=========================================

GET option.inc

GET memcfg.inc

GET 2440addr.inc

BIT_SELFREFRESH EQU (1<<22) ;bit[22]=1,others=0(把1左移22位)

;Pre-defined constants ;系統(tǒng)的工作模式設(shè)定

USERMODE EQU 0x10

FIQMODE EQU 0x11

IRQMODE EQU 0x12

SVCMODE EQU 0x13

ABORTMODE EQU 0x17

UNDEFMODE EQU 0x1b

MODEMASK EQU 0x1f

NOINT EQU 0xc0

;The location of stacks ;系統(tǒng)的堆棧空間設(shè)定

UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~

SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~

UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~

AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~

IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~

FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~

;arm處理器有兩種工作狀態(tài) 1.arm:32位 這種工作狀態(tài)下執(zhí)行字對(duì)準(zhǔn)的arm指令 2.Thumb:16位這種工作狀

;態(tài)執(zhí)行半字對(duì)準(zhǔn)的Thumb指令

;因?yàn)樘幚砥鞣譃?6位 32位兩種工作狀態(tài) 程序的編譯器也是分16位和32兩種編譯方式 所以下面的程序用

;于根據(jù)處理器工作狀態(tài)確定編譯器編譯方式

;code16偽指令指示匯編編譯器后面的指令為16位的thumb指令

;code32偽指令指示匯編編譯器后面的指令為32位的arm指令

;這段是為了統(tǒng)一目前的處理器工作狀態(tài)和軟件編譯方式（16位編譯環(huán)境使用tasm.exe編譯

;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.

GBLL THUMBCODE ;定義一個(gè)全局變量

[ {CONFIG} = 16 ;if config==16 這里表示你的目前處于領(lǐng)先地16位編譯方式

THUMBCODE SETL {TRUE} ;設(shè)置THUMBCODE 為 true表示告訴系統(tǒng)當(dāng)前想用thumb，但實(shí)際啟動(dòng)時(shí)不行，只能啟動(dòng)后再跳

; ][|]表示if else endif

CODE32 ;啟動(dòng)時(shí)強(qiáng)制使用32位編譯模式

|

THUMBCODE SETL {FALSE} ;如果系統(tǒng)要求是ARM指令，則直接設(shè)置THUMBCODE 為 false 說(shuō)明當(dāng)前的是32位編譯模式

]

MACRO ;宏定義

MOV_PC_LR

[ THUMBCODE

bx lr

|

mov pc,lr

]

MEND

MACRO

MOVEQ_PC_LR

[ THUMBCODE

bxeq lr ;相等Z=1,則跳轉(zhuǎn)

|

moveq pc,lr

]

MEND

;注意下面這段程序是個(gè)宏定義 很多人對(duì)這段程序不理解 我再次強(qiáng)調(diào)這是一個(gè)宏定義 所以大家要注意了

;下面包含的HandlerXXX HANDLER HandleXXX將都被下面這段程序展開(kāi)

;這段程序用于把中斷服務(wù)程序的首地址裝載到pc中，有人稱之為“加載程序”。

;本初始化程序定義了一個(gè)數(shù)據(jù)區(qū)（在文件最后），34個(gè)字空間，存放相應(yīng)中斷服務(wù)程序的首地址。每個(gè)字

;空間都有一個(gè)標(biāo)號(hào)，以Handle***命名。

;在向量中斷模式下使用“加載程序”來(lái)執(zhí)行中斷服務(wù)程序。

;這里就必須講一下向量中斷模式和非向量中斷模式的概念

;向量中斷模式是當(dāng)cpu讀取位于0x18處的IRQ中斷指令的時(shí)候，系統(tǒng)自動(dòng)讀取對(duì)應(yīng)于該中斷源確定地址上的;

;指令取代0x18處的指令，通過(guò)跳轉(zhuǎn)指令系統(tǒng)就直接跳轉(zhuǎn)到對(duì)應(yīng)地址

;函數(shù)中 節(jié)省了中斷處理時(shí)間提高了中斷處理速度標(biāo) 例如 ADC中斷的向量地址為0xC0,則在0xC0處放如下

;代碼：ldr PC,=HandlerADC 當(dāng)ADC中斷產(chǎn)生的時(shí)候系統(tǒng)會(huì)

;自動(dòng)跳轉(zhuǎn)到HandlerADC函數(shù)中

;非向量中斷模式處理方式是一種傳統(tǒng)的中斷處理方法，當(dāng)系統(tǒng)產(chǎn)生中斷的時(shí)候，系統(tǒng)將interrupt

;pending寄存器中對(duì)應(yīng)標(biāo)志位置位 然后跳轉(zhuǎn)到位于0x18處的統(tǒng)一中斷

;函數(shù)中 該函數(shù)通過(guò)讀取interrupt pending寄存器中對(duì)應(yīng)標(biāo)志位 來(lái)判斷中斷源 并根據(jù)優(yōu)先級(jí)關(guān)系再跳到

;對(duì)應(yīng)中斷源的處理代碼中

MACRO

$HandlerLabel HANDLER $HandleLabel

$HandlerLabel

sub sp,sp,#4 ;decrement sp(to store jump address)

stmfd sp!,{r0} ;PUSH the work register to stack(lr doest push because it return to original address)

ldr r0,=$HandleLabel;load the address of HandleXXX to r0

ldr r0,[r0] ;load the contents(service routine start address) of HandleXXX

str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack

ldmfd sp!,{r0,pc} ;POP the work register and pc(jump to ISR)

MEND

;將$HandleLabel地址空間中的數(shù)據(jù)給PC，中斷服務(wù)程序的入口

IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data)

IMPORT |Image$$RW$$Base| ; Base of RAM to initialise

IMPORT |Image$$ZI$$Base| ; Base and limit of area

IMPORT |Image$$ZI$$Limit| ; to zero initialise

IMPORT Main

;導(dǎo)入要用到的字符常量

AREA Init,CODE,READONLY

;異常中斷矢量表（每個(gè)表項(xiàng)占4個(gè)字節(jié)） 下面是中斷向量表 一旦系統(tǒng)運(yùn)行時(shí)有中斷發(fā)生 即使移植了操作

;系統(tǒng) 如linux 處理器已經(jīng)把控制權(quán)交給了操作系統(tǒng) 一旦發(fā)生中斷 處理器還是會(huì)跳轉(zhuǎn)到從0x0開(kāi)始

;中斷向量表中某個(gè)中斷表項(xiàng)（依據(jù)中斷類型）開(kāi)始執(zhí)行

;具體中斷向量布局請(qǐng)參考s3c44b0 spec 例如 adc中斷向量為 0x000000c0下面對(duì)應(yīng)表中第49項(xiàng)位置向量地址0x0+4*(49-1)=0x000000c0

ENTRY

;板子上電和復(fù)位后 程序開(kāi)始從位于0x0處開(kāi)始執(zhí)行硬件剛剛上電復(fù)位后 程序從這里開(kāi)始執(zhí)行跳轉(zhuǎn)到標(biāo)

;為ResetHandler處執(zhí)行

;1)The code, which converts to Big-endian, should be in little endian code.

;2)The following little endian code will be compiled in Big-Endian mode.

; The code byte order should be changed as the memory bus width.

;3)The pseudo instruction,DCD cant be used here because the linker generates error.

;條件編譯，在編譯成機(jī)器碼前就設(shè)定好

ASSERT :DEF:ENDIAN_CHANGE ;判斷ENDIAN_CHANGE是否已定義

[ ENDIAN_CHANGE ;如果已經(jīng)定義了ENDIAN_CHANGE，則判斷,here is FALSE

ASSERT :DEF:ENTRY_BUS_WIDTH ;判斷ENTRY_BUS_WIDTH是否已定義

][ ENTRY_BUS_WIDTH=32 ;如果已經(jīng)定義了ENTRY_BUS_WIDTH，則判斷是不是為32

b ChangeBigEndian ;DCD 0xea000007

]

;在bigendian中，地址為A的字單元包括字節(jié)單元A，A+1，A+2，A+3，字節(jié)單元由高位到低位為A，A+1，A+2，A+3

; 地址為A的字單元包括半字單元A，A+2，半字單元由高位到低位為A，A+2

[ ENTRY_BUS_WIDTH=16

andeq r14,r7,r0,lsl #20 ;DCD 0x0007ea00 也是b ChangeBigEndian指令，只是由于總線不一樣而取機(jī)器碼的順序不一樣

] ;先取低位->高位 上述指令是通過(guò)機(jī)器碼裝換而來(lái)的

[ ENTRY_BUS_WIDTH=8

streq r0,][r0,-r10,ror #1] ;DCD 0x070000ea 也是b ChangeBigEndian指令，只是由于總線不一樣而取機(jī)器碼的順序不一樣

]

|

b ResetHandler ;//here is the first instrument 0x00

]

b HandlerUndef ;handler for Undefined mode ;0x04

b HandlerSWI ;handler for SWI interrupt ;0x08

b HandlerPabort ;handler for PAbort ;0x0c

b HandlerDabort ;handler for DAbort ;0x10

b . ;reserved ;0x14

b HandlerIRQ ;handler for IRQ interrupt ;0x18

b HandlerFIQ ;handler for FIQ interrupt ;0x1c

;@0x20

b EnterPWDN ; Must be @0x20.

;通過(guò)設(shè)置CP15的C1的位7，設(shè)置存儲(chǔ)格式為Bigendian，三種總線方式

ChangeBigEndian ;//here ENTRY_BUS_WIDTH=16

;@0x24

[ ENTRY_BUS_WIDTH=32

DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0

DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80; //Big-endian

DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0

;對(duì)存儲(chǔ)器控制寄存器操作，指定內(nèi)存模式為Big-endian

;因?yàn)閯傞_(kāi)始CPU都是按照32位總線的指令格式運(yùn)行的，如果采用其他的話，CPU別不了，必須轉(zhuǎn)化

;但當(dāng)系統(tǒng)初始化好以后，則CPU能自動(dòng)識(shí)別

]

[ ENTRY_BUS_WIDTH=16

DCD 0x0f10ee11

DCD 0x0080e380

DCD 0x0f10ee01

;因?yàn)椴捎肂ig-endian模式，采用16位總線時(shí)，物理地址的高位和數(shù)據(jù)的地位對(duì)應(yīng)

;所以指令的機(jī)器碼也相應(yīng)的高低對(duì)調(diào)

]

[ ENTRY_BUS_WIDTH=8

DCD 0x100f11ee

DCD 0x800080e3

DCD 0x100f01ee

]

DCD 0xffffffff ;swinv 0xffffff is similar with NOP and run well in both endian mode.

DCD 0xffffffff

DCD 0xffffffff

DCD 0xffffffff

DCD 0xffffffff

b ResetHandler

;Function for entering power down mode

; 1. SDRAM should be in self-refresh mode.

; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.

; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.

; 4. The I-cache may have to be turned on.

; 5. The location of the following code may have not to be changed.

;void EnterPWDN(int CLKCON);

EnterPWDN

mov r2,r0 ;r2=rCLKCON 保存原始數(shù)據(jù) 0x4c00000c 使能各模塊的時(shí)鐘輸入

tst r0,#0x8 ;測(cè)試bit[3] SLEEP mode? 1=>sleep

bne ENTER_SLEEP ;C=0,即TST結(jié)果非0，bit[3]=1

;//進(jìn)入PWDN后如果不是sleep則進(jìn)入stop

;//進(jìn)入Stop mode

ENTER_STOP

ldr r0,=REFRESH ;0x48000024 DRAM/SDRAM refresh config

ldr r3,[r0] ;r3=rREFRESH

mov r1, r3

orr r1, r1, #BIT_SELFREFRESH ;Enable SDRAM self-refresh

str r1, [r0] ;Enable SDRAM self-refresh

;//Enable SDRAM self-refresh

mov r1,#16 ;wait until self-refresh is issued. may not be needed.

0 subs r1,r1,#1

bne %B0

;//wait 16 fclks for self-refresh

ldr r0,=CLKCON ;enter STOP mode.

str r2,[r0]

;//？？？？？？？？？？？？？？

mov r1,#32

0 subs r1,r1,#1 ;1) wait until the STOP mode is in effect.

bne %B0 ;2) Or wait here until the CPU&Peripherals will be turned-off

;Entering SLEEP mode, only the reset by wake-up is available.

ldr r0,=REFRESH ;exit from SDRAM self refresh mode.

str r3,[r0]

MOV_PC_LR ;back to main process

ENTER_SLEEP

;NOTE.

;1) rGSTATUS3 should have the return address after wake-up from SLEEP mode.

ldr r0,=REFRESH

ldr r1,[r0] ;r1=rREFRESH

orr r1, r1, #BIT_SELFREFRESH

str r1, [r0] ;Enable SDRAM self-refresh

;//Enable SDRAM self-refresh

mov r1,#16 ;Wait until self-refresh is issued,which may not be needed.

0 subs r1,r1,#1

bne %B0

;//Wait until self-refresh is issued,which may not be needed

ldr r1,=MISCCR ;IO register

ldr r0,[r1]

orr r0,r0,#(7<<17) ;Set SCLK0=1, SCLK1=1, SCKE=1.

str r0,[r1]

ldr r0,=CLKCON ; Enter sleep mode

str r2,[r0]

b . ;CPU will die here.

;//進(jìn)入Sleep Mode，1）設(shè)置SDRAM為self-refresh

;// 2）設(shè)置MISCCR bit[17] 1:sclk0=sclk 0:sclk0=0

;// bit[18] 1:sclk1=sclk 0:sclk1=0

;// bit[19] 1:Self refresh retain enable

;// 0:Self refresh retain disable

;// When 1, After wake-up from sleep, The self-refresh will be retained.

WAKEUP_SLEEP

;Release SCLKn after wake-up from the SLEEP mode.

ldr r1,=MISCCR

ldr r0,[r1]

bic r0,r0,#(7<<17) ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.

str r0,[r1]

;//設(shè)置MISCCR

;Set memory control registers

ldr r0,=SMRDATA

ldr r1,=BWSCON ;BWSCON Address ;//總線寬度和等待控制寄存器

add r2, r0, #52 ;End address of SMRDATA

0

ldr r3, [r0], #4 ;數(shù)據(jù)處理后R0自加4，[R0]->R3，R0+4->R0

str r3, [r1], #4

cmp r2, r0

bne %B0

;//設(shè)置所有的memory control register，他的初始地址為BWSCON，初始化

;//數(shù)據(jù)在以SMRDATA為起始的存儲(chǔ)區(qū)

mov r1,#256

0 subs r1,r1,#1 ;1) wait until the SelfRefresh is released.

bne %B0

;//1) wait until the SelfRefresh is released.

ldr r1,=GSTATUS3 ;GSTATUS3 has the start address just after SLEEP wake-up

ldr r0,[r1]

mov pc,r0

;//跳出Sleep Mode，進(jìn)入Sleep狀態(tài)前的PC

;//異常中斷宏調(diào)用

LTORG

HandlerFIQ HANDLER HandleFIQ

HandlerIRQ HANDLER HandleIRQ

HandlerUndef HANDLER HandleUndef

HandlerSWI HANDLER HandleSWI

HandlerDabort HANDLER HandleDabort

HandlerPabort HANDLER HandlePabort

IsrIRQ

sub sp,sp,#4 ;reserved for PC

stmfd sp!,{r8-r9}

ldr r9,=INTOFFSET ;地址為0x4a000014的空間存著中斷的偏移

ldr r9,[r9] ;I_ISR

ldr r8,=HandleEINT0

add r8,r8,r9,lsl #2

ldr r8,[r8]

str r8,[sp,#8]

ldmfd sp!,{r8-r9,pc}

;//外部中斷號(hào)判斷，通過(guò)中斷服務(wù)程序入口地址存儲(chǔ)器的地址偏移確定

;//PC=[HandleEINT0+][INTOFFSET]]

;=======

; ENTRY

;扳子上電和復(fù)位后 程序開(kāi)始從位于0x0執(zhí)行b ResetHandler 程序從跳轉(zhuǎn)到這里執(zhí)行

;板子上電復(fù)位后 執(zhí)行幾個(gè)步驟這里通過(guò)標(biāo)號(hào)在注釋中加1，2，3....標(biāo)示 標(biāo)號(hào)表示執(zhí)行順序

;1.禁止看門狗 屏蔽所有中斷

;=======

ResetHandler

;//1.禁止看門狗 屏蔽所有中斷

ldr r0,=WTCON ;watch dog disable

ldr r1,=0x0

str r1,[r0]

ldr r0,=INTMSK

ldr r1,=0xffffffff ;all interrupt disable

str r1,[r0]

ldr r0,=INTSUBMSK

ldr r1,=0x3ff ;all sub interrupt disable

str r1,[r0]

[ {FALSE}

;//rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);

;//Led_Display

ldr r0,=GPFCON ;//F-IO In/Out config 10 10 10 10 00 00 00 00

ldr r1,=0x5500 ;//00 = Input 01 = Output

str r1,][r0] ;//10 = EINT[0] 11 = Reserved

ldr r0,=GPFDAT ;//F-IO data register

ldr r1,=0x10

str r1,[r0]

]